home *** CD-ROM | disk | FTP | other *** search
/ Tiger Disk 128 / Tiger_Disk_128_20xx_Tiger-Crew-Disk_de_Side_B.d64 / datei 64 (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  3KB  |  110 lines
  1. 10 open15,8,15:poke53280,6:poke53281,6:
  2. 20 poke53265,11:print"[147]        ****   datei 64[146]   ****"
  3. 30 print"        (c)  1985 klaus raczek"
  4. 40 print"  1[146]  [155]datei [153]laden            *  [158]t  v[156]  i"
  5. 50 printspc(28)"*"
  6. 60 print"  2[146]  [155]datei [153]speichern        *  [158]i  e[156]  n"
  7. 70 printspc(28)"*"
  8. 80 print"  3[146]  daten [152]eingeben         *  [158]g  r"
  9. 90 printspc(28)"*"
  10. 100 print"  4[146]  daten suchen           *  [158]e  s[156]  2"
  11. 110 printspc(28)"*"
  12. 120 print"  5[146]  daten aendern          *  [158]r  i[156]  0"
  13. 130 printspc(28)"*"
  14. 140 print"  6[146]  daten loeschen         *  [158]d  o[156]  0"
  15. 150 printspc(28)"*"
  16. 160 print"  7[146]  [158]maske erstellen        *  [158]i  n[156]  4"
  17. 170 printspc(28)"*"
  18. 180 print"  8[146]  daten [152]ausgeben         *  [158]s"
  19. 190 printspc(28)"*"
  20. 200 print"  9[146]  [156]programm beenden       *  [158]k":poke53265,27
  21. 210 print"[150]     welche nummer ";
  22. 220 ch=0:inputch$:ch=val(ch$):poke2,ch:ifch=9thenend
  23. 230 ifch<1orch>8then20
  24. 240 ifch=1orch=7thenclr:ch=peek(2):open15,8,15
  25. 250 onchgosub270,340,440,510,640,680,790,850
  26. 260 gosub1030:goto20
  27. 270 print"[147]name der datei";:input"   $ [157][157][157][157]";aa$
  28. 280 ifaa$="$"thengosub1040:goto270
  29. 290 open1,8,2,aa$+",s,r":gosub760
  30. 300 input#1,fe,n,le:dimfe$(fe),s$(fe),da$(le,fe)
  31. 310 forx=1tofe:input#1,fe$(x):next
  32. 320 fori=0ton-1:forx=1tofe
  33. 330 input#1,da$(i,x):next:next:close1:gosub760:return
  34. 340 ifn=0thenprint"[145][145][145][145]":return
  35. 350 print"[147]name der datei";:input"   $ [157][157][157][157]";aa$
  36. 360 ifaa$="$"thengosub1040:goto350
  37. 370 open1,8,2,aa$+",s,w":gosub760:close1:ifa<>0then430
  38. 380 open1,8,2,aa$+",s,w"
  39. 390 print#1,fe:print#1,n:print#1,le
  40. 400 forx=1tofe:print#1,fe$(x)" ":next
  41. 410 fori=0ton-1:forx=1tofe
  42. 420 print#1,da$(i,x)" ":next:next
  43. 430 close1:gosub760:return
  44. 440 print"[147]daten eingeben /  eingabe-ende:  return "
  45. 450 l=0:forx=1tofe:da$(n,x)=""
  46. 460 print""fe$(x)"[146]: ";:inputda$(n,x):ifda$(n,1)=""thenreturn
  47. 470 ifda$(n,x)=""thenda$(n,x)="*"
  48. 480 l=l+len(da$(n,x)):next
  49. 490 ifl=0thenn=n-1
  50. 500 n=n+1:gosub1030:goto440
  51. 510 ifn=0thenprint"[145][145][145][145]":return
  52. 520 print"[147]suchen:"
  53. 530 fori=1tofe:print""fe$(i)"[146]: ";:s$(i)="":inputs$(i):s(i)=len(s$(i)):next
  54. 540 ei=0:forx=0ton-1:ff=0:fori=1tofe
  55. 550 ifleft$(da$(x,i),s(i))<>s$(i)thenff=1
  56. 560 next:ifff=0goto590
  57. 570 next:ifei=1thenreturn
  58. 580 print"eintrag nicht gefunden":return
  59. 590 iffl=1thenreturn
  60. 600 print"[147]eintrag gefunden:"
  61. 610 forj=1tofe:print""fe$(j)"[146]: "tab(15)da$(x,j):next:ei=1
  62. 620 gosub1030:ifx<ngoto570
  63. 630 return
  64. 640 ifn=0thenprint"[145][145][145][145]":return
  65. 650 print"[147]aendern:":print"suchen":fl=1:gosub530:fl=0
  66. 660 ifx>nthenreturn
  67. 670 fori=1tofe:print""fe$(i)"[146]:":print"  "da$(x,i):input"[145]";da$(x,i):next:return
  68. 680 ifn=0thenprint"[145][145][145][145]":return
  69. 690 print"[147]eintrag loeschen":print"suchen":gosub530
  70. 700 print"loeschen (j/n)"
  71. 710 geta$:ifa$=""then710
  72. 720 ifa$="j"then750
  73. 730 ifa$<>"n"then710
  74. 740 return
  75. 750 fori=1tofe:da$(x,i)=da$(n-1,i):da$(n-1,i)="":next:n=n-1:return
  76. 760 input#15,a,a$:ifa=0thenreturn
  77. 770 print""a$:ifa$="file exists"then980
  78. 780 return
  79. 790 clr:open15,8,15:print"[147]eingabemaske erstellen:"
  80. 800 input"wieviele felder";fe
  81. 810 dimfe$(fe),s$(fe):print"namen und mittlere laengen der felder   eingeben:"
  82. 820 le=0:fori=1tofe:printi;:inputfe$(i),x:le=le+x:next
  83. 830 le=((fre(x)+65536)/(le+fe*3+3)):dimda$(le,fe)
  84. 840 print"es ist platz fuer"int(le)"datensaetze.":goto260
  85. 850 ifn=0thenprint"[145][145][145][145]":return
  86. 860 print"[147]daten ausgeben"
  87. 870 print"b[146]ildschirm oder d[146]rucker ?"
  88. 880 getag$:ifag$<>"b"andag$<>"d"andag$<>chr$(13)then880
  89. 890 ifag$=chr$(13)thenreturn
  90. 900 ifag$="b"then920
  91. 910 ifag$="d"thenprint"  drucker einschalten ! ":gosub970:goto940
  92. 920 forx=0ton-1:print"[147]"
  93. 930 forj=1tofe:print""fe$(j)"[146]: "tab(15)da$(x,j):next:gosub970:next:return
  94. 940 open4,4,0:forx=0ton-1
  95. 950 forj=1tofe:print#4,spc(5)da$(x,j):next:print#4:print#4:next
  96. 960 print#4:close4:return
  97. 970 poke198,0:wait198,1:poke198,0:return
  98. 980 print"bestehende datei loeschen ?"
  99. 990 getlo$:iflo$<>"j"andlo$<>"n"then990
  100. 1000 iflo$="n"thenreturn
  101. 1010 print#15,"s:"+aa$
  102. 1020 a=0:return
  103. 1030 print"    taste druecken [146]     ":poke198,0:wait198,1:poke198,0:return
  104. 1040 print"[147]":open1,8,0,"$":poke781,1:sys65478:getda$,da$:de$=chr$(0)
  105. 1050 getda$,da$,dh$,dl$:ifstthensys65484:close1:goto1090
  106. 1060 printasc(dh$+de$)+256*asc(dl$+de$);
  107. 1070 getda$,db$:ifda$thenprintda$db$;:goto1070
  108. 1080 printda$:goto1050
  109. 1090 gosub1030:return
  110.